blob: 90145b62b54b2b8050ee077cffdebc4118684455 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
/*
* Copyright (C) 2009 IBM Corp.
* This file is part of systemtap, and is free software. You can
* redistribute it and/or modify it under the terms of the GNU General
* Public License (GPL); either version 2, or (at your option) any
* later version.
*
* Version 1.0 wilder@us.ibm.com 2009-07-06
*/
global DelayedACKs /* LINUX_MIB_DELAYEDACKS */
global ListenOverflows /* LINUX_MIB_LISTENOVERFLOWS */
global ListenDrops /* LINUX_MIB_LISTENDROPS */
global TCPMemoryPressures /* LINUX_MIB_TCPMEMORYPRESSURES */
/**
* probe tcpmib.DelayedACKs - Count of delayed acks.
* @sk: Pointer to the struct sock being acted on.
* @op: Value to be added to the counter (Operation).
*
* Counter Name: DelayedACKs
* MIB: LINUX_MIB_DELAYEDACKS
*
*/
global indelack_timer
probe linuxmib.DelayedACKs = _linuxmib.DelayedACKs.* {}
probe _linuxmib.DelayedACKs.A = kernel.function("tcp_send_ack")
{
sk=$sk
if ( !indelack_timer[sk] ) next
op=1
key = linuxmib_filter_key(sk,op);
if ( key ) DelayedACKs[key] += op;
}
probe _linuxmib.DelayedACKs.B = kernel.function("tcp_delack_timer")
{
sk=$data
indelack_timer[sk]=1
}
probe _linuxmib.DelayedACKs.C = kernel.function("tcp_delack_timer").return
{
sk=$data
indelack_timer[sk]=0;
}
/**
* probe tcpmib.ListenOverflows - Count of times a listen queue overflowed
* @sk: Pointer to the struct sock being acted on.
* @op: Value to be added to the counter (Operation).
*
* Counter Name: ListenOverflows
* MIB: LINUX_MIB_LISTENOVERFLOWS
*
*/
probe linuxmib.ListenOverflows=kernel.function("tcp_v4_syn_recv_sock").return
{
sk = $sk
if ( $return ) next
if ( $sk->sk_ack_backlog <= $sk->sk_max_ack_backlog ) next
op = 1;
key = linuxmib_filter_key(sk,op);
if ( key ) ListenOverflows[key] += op;
}
/**
* probe tcpmib.ListenDrops - Count of times conn request that were dropped.
* @sk: Pointer to the struct sock being acted on.
* @op: Value to be added to the counter (Operation).
*
* Counter Name: ListenDrops
* MIB: LINUX_MIB_LISTENDROPS
*
*/
probe linuxmib.ListenDrops=kernel.function("tcp_v4_syn_recv_sock").return
{
sk = $sk
if ( $return ) next
op = 1;
key = linuxmib_filter_key(sk,op);
if ( key ) ListenDrops[key] += op;
}
/**
* probe tcpmib.TCPMemoryPressures - Count of times memory pressure was used.
* @sk: Pointer to the struct sock being acted on.
* @op: Value to be added to the counter (Operation).
*
* Counter Name: TCPMemoryPressures
* MIB: LINUX_MIB_TCPMEMORYPRESSURES
*
*/
probe linuxmib.TCPMemoryPressures=kernel.function("tcp_enter_memory_pressure")
{
%( kernel_v >= "2.6.27" %?
sk = $sk
%:
sk = 0;
%)
op = 1;
if ( $tcp_memory_pressure ) next
key = linuxmib_filter_key(sk,op);
if ( key ) TCPMemoryPressures[key] += op;
}
|
