Merge commit 'origin/master' into pr4225

* commit 'origin/master': (34 commits)
  PR5049: fix overbroad effects of naive "*" prefixing; instead use optional "*/" only.
  stap-serverd was incorectly determining that the server could
  stapprobes man page: clarify statement(NUM).absolute and process("path") searching
  PR5049: prefix with "*" any filenames given in "fn@filename:line" probes
  Indentation fix.
  Redirect stderr gets redircted so warnings don't let example script run fail.
  PR6835. io/io_submit.stp: Fix #! start. Convert to normal line-ending.
  PR2895. Add proper #! /usr/bin/env stap line. Make example scripts executable.
  Use INSTALL_PROGRAM, not INSTALL_DATA for executable .stp scripts.
  example index: only warn if old, do not regenerate
  Start/stop the systemtap server from systemtap.exp and not in the top level Makefile.
  Lower statement wildcard test matching threshold.
  Moved details of utrace detach to stap_utrace_detach().
  Saves thread vma information.
  Always generate examples indexes and install examples from srcdir.
  Refer to srcdir spec file Makefile so make rpm works when builddir != srcdir.
  Add index of subsystem and keywords at top of HTML indexes.
  Don't output output, exits, status line in indexes (mentioned in descriptions).
  Disable chmodding of samples/kmalloc-top in spec file since it isn't installed.
  Make sure examples indexes are always generated in builddir.
  ...

1 files changed, 55 insertions, 0 deletions

diff --git a/testsuite/systemtap.examples/process/proc_snoop.stp b/testsuite/systemtap.examples/process/proc_snoop.stp
new file mode 100755
index 00000000..5203c93f
--- /dev/null
+++ b/testsuite/systemtap.examples/process/proc_snoop.stp
@@ -0,0 +1,55 @@
+#! /usr/bin/env stap
+
+global start_ts
+
+probe begin {
+    start_ts = gettimeofday_us()
+    printf("%12s  %5s  %5s  %-16s  ACTION\n",
+            "TIMESTAMP", "PID", "TID", "EXECNAME")
+}
+
+function report(action:string) {
+    printf("%12d  %5d  %5d  %-16s  %s\n", gettimeofday_us() - start_ts,
+            pid(), tid(), execname(), action)
+}
+
+function id:string(task:long) {
+    return sprintf("p:%d t:%d n:%s", task_pid(task), task_tid(task),
+            task_execname(task))
+}
+
+probe process.create {
+    report(sprintf("create %s", id(task)))
+}
+
+probe process.start {
+    report("start")
+}
+
+probe process.exec {
+    report(sprintf("exec %s", filename))
+}
+
+probe process.exec_complete {
+    if (success)
+        report("exec success")
+    else
+        report(sprintf("exec failed %d (%s)", errno, errno_str(errno)))
+}
+
+probe process.exit {
+    report(sprintf("exit %d", code))
+}
+
+probe process.release {
+    report(sprintf("remove %s", id(task)))
+}
+
+probe signal.send {
+    report(sprintf("sigsend %d (%s) to %s%s", sig, sig_name, id(task),
+                shared? " [SHARED]" : ""))
+}
+
+probe signal.handle {
+    report(sprintf("sighandle %d (%s)", sig, sig_name))
+}