Merge commit 'origin/master' into pr4225

* commit 'origin/master': (34 commits)
  PR5049: fix overbroad effects of naive "*" prefixing; instead use optional "*/" only.
  stap-serverd was incorectly determining that the server could
  stapprobes man page: clarify statement(NUM).absolute and process("path") searching
  PR5049: prefix with "*" any filenames given in "fn@filename:line" probes
  Indentation fix.
  Redirect stderr gets redircted so warnings don't let example script run fail.
  PR6835. io/io_submit.stp: Fix #! start. Convert to normal line-ending.
  PR2895. Add proper #! /usr/bin/env stap line. Make example scripts executable.
  Use INSTALL_PROGRAM, not INSTALL_DATA for executable .stp scripts.
  example index: only warn if old, do not regenerate
  Start/stop the systemtap server from systemtap.exp and not in the top level Makefile.
  Lower statement wildcard test matching threshold.
  Moved details of utrace detach to stap_utrace_detach().
  Saves thread vma information.
  Always generate examples indexes and install examples from srcdir.
  Refer to srcdir spec file Makefile so make rpm works when builddir != srcdir.
  Add index of subsystem and keywords at top of HTML indexes.
  Don't output output, exits, status line in indexes (mentioned in descriptions).
  Disable chmodding of samples/kmalloc-top in spec file since it isn't installed.
  Make sure examples indexes are always generated in builddir.
  ...

1 files changed, 36 insertions, 0 deletions

diff --git a/testsuite/systemtap.examples/process/futexes.stp b/testsuite/systemtap.examples/process/futexes.stp
new file mode 100755
index 00000000..16c62937
--- /dev/null
+++ b/testsuite/systemtap.examples/process/futexes.stp
@@ -0,0 +1,36 @@
+#! /usr/bin/env stap
+
+# This script tries to identify contended user-space locks by hooking
+# into the futex system call.
+
+global thread_thislock # short
+global thread_blocktime # 
+global FUTEX_WAIT = 0 /*, FUTEX_WAKE = 1 */
+
+global lock_waits # long-lived stats on (tid,lock) blockage elapsed time
+global process_names # long-lived pid-to-execname mapping
+
+probe syscall.futex {  
+   if (op != FUTEX_WAIT) next  # we don't care about originators of WAKE events
+   t = tid ()
+   process_names[pid()] = execname()
+   thread_thislock[t] = $uaddr
+   thread_blocktime[t] = gettimeofday_us()
+}
+
+probe syscall.futex.return {  
+   t = tid()
+   ts = thread_blocktime[t]
+   if (ts) {
+     elapsed = gettimeofday_us() - ts
+     lock_waits[pid(), thread_thislock[t]] <<< elapsed
+     delete thread_blocktime[t]
+     delete thread_thislock[t]
+   }
+}
+
+probe end {
+   foreach ([pid+, lock] in lock_waits) 
+     printf ("%s[%d] lock %p contended %d times, %d avg us\n",
+       process_names[pid], pid, lock, @count(lock_waits[pid,lock]), @avg(lock_waits[pid,lock]))
+}