Merge commit 'origin/master' into pr4225

* commit 'origin/master': (34 commits)
  PR5049: fix overbroad effects of naive "*" prefixing; instead use optional "*/" only.
  stap-serverd was incorectly determining that the server could
  stapprobes man page: clarify statement(NUM).absolute and process("path") searching
  PR5049: prefix with "*" any filenames given in "fn@filename:line" probes
  Indentation fix.
  Redirect stderr gets redircted so warnings don't let example script run fail.
  PR6835. io/io_submit.stp: Fix #! start. Convert to normal line-ending.
  PR2895. Add proper #! /usr/bin/env stap line. Make example scripts executable.
  Use INSTALL_PROGRAM, not INSTALL_DATA for executable .stp scripts.
  example index: only warn if old, do not regenerate
  Start/stop the systemtap server from systemtap.exp and not in the top level Makefile.
  Lower statement wildcard test matching threshold.
  Moved details of utrace detach to stap_utrace_detach().
  Saves thread vma information.
  Always generate examples indexes and install examples from srcdir.
  Refer to srcdir spec file Makefile so make rpm works when builddir != srcdir.
  Add index of subsystem and keywords at top of HTML indexes.
  Don't output output, exits, status line in indexes (mentioned in descriptions).
  Disable chmodding of samples/kmalloc-top in spec file since it isn't installed.
  Make sure examples indexes are always generated in builddir.
  ...

1 files changed, 113 insertions, 0 deletions

diff --git a/testsuite/systemtap.examples/io/iotime.stp b/testsuite/systemtap.examples/io/iotime.stp
new file mode 100755
index 00000000..4fbd6b6e
--- /dev/null
+++ b/testsuite/systemtap.examples/io/iotime.stp
@@ -0,0 +1,113 @@
+#! /usr/bin/env stap
+
+/*
+ * Copyright (C) 2006-2007 Red Hat Inc.
+ * 
+ * This copyrighted material is made available to anyone wishing to use,
+ * modify, copy, or redistribute it subject to the terms and conditions
+ * of the GNU General Public License v.2.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program; if not, write to the Free Software Foundation,
+ * Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
+ *
+ * Print out the amount of time spent in the read and write systemcall
+ * when a process closes each file is closed. Note that the systemtap 
+ * script needs to be running before the open operations occur for
+ * the script to record data.
+ *
+ * This script could be used to to find out which files are slow to load
+ * on a machine. e.g.
+ *
+ * stap iotime.stp -c 'firefox'
+ *
+ * Output format is:
+ * timestamp pid (executabable) info_type path ...
+ *
+ * 200283135 2573 (cupsd) access /etc/printcap read: 0 write: 7063
+ * 200283143 2573 (cupsd) iotime /etc/printcap time: 69
+ *
+ */
+
+global start
+global entry_io
+global fd_io
+global time_io
+
+function timestamp:long() {
+  return gettimeofday_us() - start
+}
+
+function proc:string() {
+  return sprintf("%d (%s)", pid(), execname())
+}
+
+probe begin {
+ start = gettimeofday_us()
+}
+
+global filenames
+global filehandles
+global fileread
+global filewrite
+
+probe syscall.open {
+  filenames[pid()] = user_string($filename)
+} 
+
+probe syscall.open.return {
+  if ($return != -1) {
+    filehandles[pid(), $return] = filenames[pid()]
+    fileread[pid(), $return] = 0
+    filewrite[pid(), $return] = 0
+  } else {
+    printf("%d %s access %s fail\n", timestamp(), proc(), filenames[pid()])
+  }
+  delete filenames[pid()]
+}
+
+probe syscall.read {
+  if ($count > 0) {
+    fileread[pid(), $fd] += $count
+  }
+  t = gettimeofday_us(); p = pid()
+  entry_io[p] = t
+  fd_io[p] = $fd
+}
+
+probe syscall.read.return {
+  t = gettimeofday_us(); p = pid()
+  fd = fd_io[p]
+  time_io[p,fd] <<< t - entry_io[p]
+}
+
+probe syscall.write {
+  if ($count > 0) {
+    filewrite[pid(), $fd] += $count
+  }
+  t = gettimeofday_us(); p = pid()
+  entry_io[p] = t
+  fd_io[p] = $fd
+}
+
+probe syscall.write.return {
+  t = gettimeofday_us(); p = pid()
+  fd = fd_io[p]
+  time_io[p,fd] <<< t - entry_io[p]
+}
+
+probe syscall.close {
+  if (filehandles[pid(), $fd] != "") {
+    printf("%d %s access %s read: %d write: %d\n",  timestamp(), proc(),
+	filehandles[pid(), $fd], fileread[pid(), $fd], filewrite[pid(), $fd])
+    if (@count(time_io[pid(), $fd]))
+      printf("%d %s iotime %s time: %d\n",  timestamp(), proc(),
+	filehandles[pid(), $fd], @sum(time_io[pid(), $fd]))
+   }
+  delete fileread[pid(), $fd]
+  delete filewrite[pid(), $fd]
+  delete filehandles[pid(), $fd]
+  delete fd_io[pid()]
+  delete entry_io[pid()]
+  delete time_io[pid(),$fd]
+}