Add initial configure scripts

1 files changed, 85 insertions, 0 deletions

diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..e65a44a
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,85 @@
+AC_PREREQ([2.69])
+AC_INIT([mod_auth_gssapi], [0.0.1], [simo@redhat.com])
+AC_CONFIG_SRCDIR([src/mod_auth_gssapi.c])
+AM_INIT_AUTOMAKE
+AC_CONFIG_MACRO_DIR([m4])
+AC_CONFIG_HEADERS([config.h])
+
+# Checks for programs.
+AC_PROG_CC
+
+AC_PROG_LIBTOOL
+AC_SUBST(INCLTDL)
+AC_SUBST(LIBLTDL)
+
+AM_CONDITIONAL([HAVE_GCC], [test "$ac_cv_prog_gcc" = yes])
+
+AC_CHECK_HEADERS([stdint.h])
+
+# Checks for typedefs, structures, and compiler characteristics.
+AC_CHECK_HEADER_STDBOOL
+AC_TYPE_SIZE_T
+AC_TYPE_UINT32_T
+
+# Checks for library functions.
+AC_CHECK_FUNCS([strcasecmp])
+
+AC_ARG_WITH([apxs],
+            [AC_HELP_STRING([--with-apxs=PATH/NAME], [path to the apxs binary [[apxs]]])],
+            [AC_SUBST(APXS, $with_apxs)],
+            [AC_PATH_PROGS(APXS, [apxs2 apxs])])
+AS_IF([test "x${APXS}" != "x" -a -x "${APXS}"],
+      [AC_MSG_NOTICE([apxs found at $APXS])
+       APXS_CPPFLAGS=`${APXS} -q CFLAGS`
+       AC_SUBST(APXS_CPPFLAGS)
+       APXS_LDFLAGS=`${APXS} -q LDFLAGS_SHLIB`
+       AC_SUBST(APXS_LDFLAGS)
+       APXS_LIBS=`${APXS} -q LIBS_SHLIB`
+       AC_SUBST(APXS_LIBS)
+       APXS_INCLUDES=-I`${APXS} -q INCLUDEDIR`
+       AC_SUBST(APXS_INCLUDES)
+       APXS_CPPFLAGS_SHLIB=`${APXS} -q CFLAGS_SHLIB`
+       AC_SUBST(APXS_CPPFLAGS_SHLIB)
+       APXS_LD_SHLIB=`${APXS} -q LD_SHLIB`
+       AC_SUBST(APXS_LD_SHLIB)
+       APXS_LIBEXECDIR=`${APXS} -q LIBEXECDIR`
+       AC_SUBST(APXS_LIBEXECDIR)
+       APXS_SYSCONFDIR=`${APXS} -q SYSCONFDIR`
+       AC_SUBST(APXS_SYSCONFDIR)
+       APXS_PREFIX=`${APXS} -q PREFIX`
+       AC_SUBST(APXS_PREFIX)],
+      [AC_MSG_FAILURE(["apxs not found. Use --with-apxs"])])
+
+AC_ARG_WITH([apr],
+            [AC_HELP_STRING([--with-apr=PATH/NAME], [path to the apr binary [[apr]]])],
+            [AC_SUBST(APR, $with_apr)],
+            [AC_PATH_PROGS(APR, [apr-1-config])])
+AS_IF([test "x${APR}" != "x" -a -x "${APR}"],
+      [AC_MSG_NOTICE([apr found at $APR])
+       APR_CPPFLAGS=`${APR} --cppflags`
+       AC_SUBST(APR_CPPFLAGS)
+       APR_INCLUDES=`${APR} --includes`
+       AC_SUBST(APR_INCLUDES)
+       APR_LDFLAGS=`${APR} --link-libtool --libs`
+       AC_SUBST(APR_LDFLAGS)],
+      [AC_MSG_FAILURE(["apr-1-config not found. Use --with-apr"])])
+
+AC_CHECK_HEADERS([gssapi/gssapi.h],,[AC_MSG_ERROR([Could not find GSSAPI headers])])
+AC_PATH_PROG(KRB5_CONFIG, krb5-config, failed)
+if test x$KRB5_CONFIG = xfailed; then
+    AC_MSG_ERROR([Could not find GSSAPI development libraries])
+else
+    GSSAPI_CFLAGS="`$KRB5_CONFIG --cflags gssapi`"
+    GSSAPI_LIBS="`$KRB5_CONFIG --libs gssapi`"
+fi
+AC_CHECK_LIB([gssapi_krb5], [gss_accept_sec_context], [],
+             [AC_MSG_ERROR([GSSAPI library check failed])])
+AC_CHECK_FUNCS(gss_acquire_cred_from)
+AC_CHECK_FUNCS(gss_store_cred_into)
+
+AC_SUBST([GSSAPI_CFLAGS])
+AC_SUBST([GSSAPI_LIBS])
+
+AC_CONFIG_FILES([Makefile src/Makefile])
+
+AC_OUTPUT