Empty build system

1 files changed, 95 insertions, 0 deletions

diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..ed53177
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,95 @@
+# Process this file with autoconf to produce a configure script.
+# FIXME: bug report address, URL
+AC_INIT([ncrypto], [0.1])
+AC_COPYRIGHT(
+[Copyright 2010 Red Hat, Inc.
+
+Redistribution and use in source and binary forms, with or without
+modification, are permitted provided that the following conditions are met:
+
+1. Redistributions of source code must retain the above copyright notice, this
+   list of conditions and the following disclaimer.
+
+2. Redistributions in binary form must reproduce the above copyright notice,
+   this list of conditions and the following disclaimer in the documentation
+   and/or other materials provided with the distribution.
+
+THIS SOFTWARE IS PROVIDED BY CONTRIBUTORS ``AS IS'' AND ANY EXPRESS OR IMPLIED
+WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
+MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO
+EVENT SHALL CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR
+BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER
+IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+POSSIBILITY OF SUCH DAMAGE.
+
+Red Hat author: Miloslav Trmač <mitr@redhat.com>
+])
+AC_PREREQ([2.65])
+AC_CONFIG_HEADERS([config.h])
+AC_CONFIG_MACRO_DIR([m4])
+AC_CONFIG_SRCDIR([include/ncrypto/ncrypto.h])
+AC_CONFIG_AUX_DIR([admin])
+AM_INIT_AUTOMAKE([no-dist-gzip dist-xz no-define subdir-objects -Wall])
+AM_SILENT_RULES([yes])
+
+# Checks for programs.
+AC_PROG_CC
+AM_PROG_CC_C_O
+
+# This interface seems to be undocumented, but bison uses it ;-)
+AM_MISSING_PROG([AUTOM4TE], [autom4te])
+
+LT_INIT([disable-static])
+
+# Checks for libraries.
+PKG_CHECK_MODULES(GLIB,[glib-2.0])
+AC_DEFINE(G_DISABLE_DEPRECATED,,
+	[Stay away from deprecated glib functionality.])
+PKG_CHECK_MODULES(NSS,[nss])
+
+# Checks for header files.
+
+# Checks for types.
+
+# Checks for structures.
+
+# Checks for compiler characteristics.
+
+# Checks for library functions.
+
+# Checks for system services.
+AC_SYS_LARGEFILE
+
+# Miscellanous hackery.
+
+# Modify CFLAGS after all tests are run (some of them would fail because
+# of the -Werror).
+if test "$GCC" = yes ; then
+    AC_CACHE_CHECK([for available GCC warning flags],
+		   [mitr_cv_prog_gcc_warnings],
+    [mitr_cv_prog_gcc_warnings=""
+    for i in -Wall -W -Wcast-align -Wmissing-noreturn -Wnested-externs dnl
+ -Wpointer-arith -Wshadow -Wstrict-prototypes -Wwrite-strings -Wundef; do
+        oldcflags=$CFLAGS
+        CFLAGS="$CFLAGS $i"
+        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])],
+		[mitr_cv_prog_gcc_warnings="$mitr_cv_prog_gcc_warnings $i"])
+	CFLAGS=$oldcflags
+     done])
+     CFLAGS="$CFLAGS $mitr_cv_prog_gcc_warnings"
+     AC_MSG_CHECKING([whether we should use -Werror])
+     AC_ARG_ENABLE([Werror],
+		   AS_HELP_STRING([--enable-Werror],
+			[use -Werror if compiling with gcc (default is NO)]),
+		   [], enable_Werror=no)
+     if test "x$enable_Werror" != xno; then
+	CFLAGS="$CFLAGS -Werror"
+     fi
+     AC_MSG_RESULT([$enable_Werror])
+fi
+
+AC_CONFIG_FILES([Makefile])
+AC_OUTPUT