Initial commitHEADmaster

21 files changed, 965 insertions, 0 deletions

diff --git a/after/ftplugin/qf.vim b/after/ftplugin/qf.vim
new file mode 100644
index 0000000..290f22d
--- /dev/null
+++ b/after/ftplugin/qf.vim
@@ -0,0 +1 @@
+nnoremap <buffer> o <CR><C-W>p
diff --git a/autoload/ShowTrailingWhitespace.vim b/autoload/ShowTrailingWhitespace.vim
new file mode 100644
index 0000000..cb7c5a8
--- /dev/null
+++ b/autoload/ShowTrailingWhitespace.vim
@@ -0,0 +1,110 @@
+" ShowTrailingWhitespace.vim: Detect unwanted whitespace at the end of lines.
+"
+" DEPENDENCIES:
+"
+" Copyright: (C) 2012 Ingo Karkat
+"   The VIM LICENSE applies to this script; see ':help copyright'.
+"
+" Maintainer:	Ingo Karkat <ingo@karkat.de>
+"
+" REVISION	DATE		REMARKS
+"   1.00.004	06-Mar-2012	Toggle to value 2 when enabled but the buffer is
+"				filtered from showing trailing whitespace.
+"	003	05-Mar-2012	Introduce g:ShowTrailingWhitespace_FilterFunc to
+"				disable highlighting for non-persisted and
+"				nomodifiable buffers.
+"	002	02-Mar-2012	Introduce b:ShowTrailingWhitespace_ExtraPattern
+"				to be able to avoid some matches (e.g. a <Space>
+"				in column 1 in a buffer with filetype=diff) and
+"				ShowTrailingWhitespace#SetLocalExtraPattern() to
+"				set it.
+"	001	25-Feb-2012	file creation
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! ShowTrailingWhitespace#Pattern( isInsertMode )
+    return (exists('b:ShowTrailingWhitespace_ExtraPattern') ? b:ShowTrailingWhitespace_ExtraPattern : '') .
+    \	(a:isInsertMode ? '\s\+\%#\@<!$' : '\s\+$')
+endfunction
+let s:HlGroupName = 'ShowTrailingWhitespace'
+function! s:UpdateMatch( isInsertMode )
+    let l:pattern = ShowTrailingWhitespace#Pattern(a:isInsertMode)
+    if exists('w:ShowTrailingWhitespace_Match')
+	" Info: matchadd() does not consider the 'magic' (it's always on),
+	" 'ignorecase' and 'smartcase' settings.
+	silent! call matchdelete(w:ShowTrailingWhitespace_Match)
+	call matchadd(s:HlGroupName, pattern, -1, w:ShowTrailingWhitespace_Match)
+    else
+	let w:ShowTrailingWhitespace_Match =  matchadd(s:HlGroupName, pattern)
+    endif
+endfunction
+function! s:DeleteMatch()
+    if exists('w:ShowTrailingWhitespace_Match')
+	silent! call matchdelete(w:ShowTrailingWhitespace_Match)
+	unlet w:ShowTrailingWhitespace_Match
+    endif
+endfunction
+
+function! s:DetectAll()
+    let l:currentWinNr = winnr()
+
+    " By entering a window, its height is potentially increased from 0 to 1 (the
+    " minimum for the current window). To avoid any modification, save the window
+    " sizes and restore them after visiting all windows.
+    let l:originalWindowLayout = winrestcmd()
+
+    noautocmd windo call ShowTrailingWhitespace#Detect(0)
+    execute l:currentWinNr . 'wincmd w'
+    silent! execute l:originalWindowLayout
+endfunction
+
+function! ShowTrailingWhitespace#IsSet()
+    return (exists('b:ShowTrailingWhitespace') ? b:ShowTrailingWhitespace : g:ShowTrailingWhitespace)
+endfunction
+function! ShowTrailingWhitespace#NotFiltered()
+    let l:Filter = (exists('b:ShowTrailingWhitespace_FilterFunc') ? b:ShowTrailingWhitespace_FilterFunc : g:ShowTrailingWhitespace_FilterFunc)
+    return (empty(l:Filter) ? 1 : call(l:Filter, []))
+endfunction
+
+function! ShowTrailingWhitespace#Detect( isInsertMode )
+    if ShowTrailingWhitespace#IsSet() && ShowTrailingWhitespace#NotFiltered()
+	call s:UpdateMatch(a:isInsertMode)
+    else
+	call s:DeleteMatch()
+    endif
+endfunction
+
+" The showing of trailing whitespace be en-/disabled globally or only for a particular buffer.
+function! ShowTrailingWhitespace#Set( isTurnOn, isGlobal )
+    if a:isGlobal
+	let g:ShowTrailingWhitespace = a:isTurnOn
+	call s:DetectAll()
+    else
+	let b:ShowTrailingWhitespace = a:isTurnOn
+	call ShowTrailingWhitespace#Detect(0)
+    endif
+endfunction
+function! ShowTrailingWhitespace#Reset()
+    unlet! b:ShowTrailingWhitespace
+    call ShowTrailingWhitespace#Detect(0)
+endfunction
+function! ShowTrailingWhitespace#Toggle( isGlobal )
+    if a:isGlobal
+	let l:newState = ! g:ShowTrailingWhitespace
+    else
+	if ShowTrailingWhitespace#NotFiltered()
+	    let l:newState = ! ShowTrailingWhitespace#IsSet()
+	else
+	    let l:newState = (ShowTrailingWhitespace#IsSet() > 1 ? 0 : 2)
+	endif
+    endif
+
+    call ShowTrailingWhitespace#Set(l:newState, a:isGlobal)
+endfunction
+
+function! ShowTrailingWhitespace#SetLocalExtraPattern( pattern )
+    let b:ShowTrailingWhitespace_ExtraPattern = a:pattern
+    call s:DetectAll()
+endfunction
+
+" vim: set ts=8 sts=4 sw=4 noexpandtab ff=unix fdm=syntax :
diff --git a/autoload/ShowTrailingWhitespace/Filter.vim b/autoload/ShowTrailingWhitespace/Filter.vim
new file mode 100644
index 0000000..2f0dc20
--- /dev/null
+++ b/autoload/ShowTrailingWhitespace/Filter.vim
@@ -0,0 +1,30 @@
+" ShowTrailingWhitespace/Filter.vim: Exclude certain buffers from detection.
+"
+" DEPENDENCIES:
+"
+" Copyright: (C) 2012 Ingo Karkat
+"   The VIM LICENSE applies to this script; see ':help copyright'.
+"
+" Maintainer:	Ingo Karkat <ingo@karkat.de>
+"
+" REVISION	DATE		REMARKS
+"   1.00.002	06-Mar-2012	Modularize conditionals.
+"				Also do not normally show 'binary' buffers.
+"	001	05-Mar-2012	file creation
+
+function! s:IsPersistedBuffer()
+    return ! (&l:buftype ==# 'nofile' || &l:buftype ==# 'nowrite')
+endfunction
+function! s:IsScratchBuffer()
+    return (bufname('') =~# '\[Scratch]')
+endfunction
+function! s:IsForcedShow()
+    return (ShowTrailingWhitespace#IsSet() == 2)
+endfunction
+
+function! ShowTrailingWhitespace#Filter#Default()
+    let l:isShownNormally = &l:modifiable && ! &l:binary && (s:IsPersistedBuffer() || s:IsScratchBuffer())
+    return l:isShownNormally || s:IsForcedShow()
+endfunction
+
+" vim: set ts=8 sts=4 sw=4 noexpandtab ff=unix fdm=syntax :
diff --git a/autoload/pathogen.vim b/autoload/pathogen.vim
new file mode 100644
index 0000000..57ca1bd
--- /dev/null
+++ b/autoload/pathogen.vim
@@ -0,0 +1,328 @@
+" pathogen.vim - path option manipulation
+" Maintainer:   Tim Pope <http://tpo.pe/>
+" Version:      2.2
+
+" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
+"
+" For management of individually installed plugins in ~/.vim/bundle (or
+" ~\vimfiles\bundle), adding `call pathogen#infect()` to the top of your
+" .vimrc is the only other setup necessary.
+"
+" The API is documented inline below.  For maximum ease of reading,
+" :set foldmethod=marker
+
+if exists("g:loaded_pathogen") || &cp
+  finish
+endif
+let g:loaded_pathogen = 1
+
+function! s:warn(msg)
+  if &verbose
+    echohl WarningMsg
+    echomsg a:msg
+    echohl NONE
+  endif
+endfunction
+
+" Point of entry for basic default usage.  Give a relative path to invoke
+" pathogen#incubate() (defaults to "bundle/{}"), or an absolute path to invoke
+" pathogen#surround().  For backwards compatibility purposes, a full path that
+" does not end in {} or * is given to pathogen#runtime_prepend_subdirectories()
+" instead.
+function! pathogen#infect(...) abort " {{{1
+  for path in a:0 ? reverse(copy(a:000)) : ['bundle/{}']
+    if path =~# '^[^\\/]\+$'
+      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+      call pathogen#incubate(path . '/{}')
+    elseif path =~# '^[^\\/]\+[\\/]\%({}\|\*\)$'
+      call pathogen#incubate(path)
+    elseif path =~# '[\\/]\%({}\|\*\)$'
+      call pathogen#surround(path)
+    else
+      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+      call pathogen#surround(path . '/{}')
+    endif
+  endfor
+  call pathogen#cycle_filetype()
+  return ''
+endfunction " }}}1
+
+" Split a path into a list.
+function! pathogen#split(path) abort " {{{1
+  if type(a:path) == type([]) | return a:path | endif
+  let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
+  return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
+endfunction " }}}1
+
+" Convert a list to a path.
+function! pathogen#join(...) abort " {{{1
+  if type(a:1) == type(1) && a:1
+    let i = 1
+    let space = ' '
+  else
+    let i = 0
+    let space = ''
+  endif
+  let path = ""
+  while i < a:0
+    if type(a:000[i]) == type([])
+      let list = a:000[i]
+      let j = 0
+      while j < len(list)
+        let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
+        let path .= ',' . escaped
+        let j += 1
+      endwhile
+    else
+      let path .= "," . a:000[i]
+    endif
+    let i += 1
+  endwhile
+  return substitute(path,'^,','','')
+endfunction " }}}1
+
+" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
+function! pathogen#legacyjoin(...) abort " {{{1
+  return call('pathogen#join',[1] + a:000)
+endfunction " }}}1
+
+" Remove duplicates from a list.
+function! pathogen#uniq(list) abort " {{{1
+  let i = 0
+  let seen = {}
+  while i < len(a:list)
+    if (a:list[i] ==# '' && exists('empty')) || has_key(seen,a:list[i])
+      call remove(a:list,i)
+    elseif a:list[i] ==# ''
+      let i += 1
+      let empty = 1
+    else
+      let seen[a:list[i]] = 1
+      let i += 1
+    endif
+  endwhile
+  return a:list
+endfunction " }}}1
+
+" \ on Windows unless shellslash is set, / everywhere else.
+function! pathogen#separator() abort " {{{1
+  return !exists("+shellslash") || &shellslash ? '/' : '\'
+endfunction " }}}1
+
+" Convenience wrapper around glob() which returns a list.
+function! pathogen#glob(pattern) abort " {{{1
+  let files = split(glob(a:pattern),"\n")
+  return map(files,'substitute(v:val,"[".pathogen#separator()."/]$","","")')
+endfunction "}}}1
+
+" Like pathogen#glob(), only limit the results to directories.
+function! pathogen#glob_directories(pattern) abort " {{{1
+  return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
+endfunction "}}}1
+
+" Turn filetype detection off and back on again if it was already enabled.
+function! pathogen#cycle_filetype() " {{{1
+  if exists('g:did_load_filetypes')
+    filetype off
+    filetype on
+  endif
+endfunction " }}}1
+
+" Check if a bundle is disabled.  A bundle is considered disabled if it ends
+" in a tilde or its basename or full name is included in the list
+" g:pathogen_disabled.
+function! pathogen#is_disabled(path) " {{{1
+  if a:path =~# '\~$'
+    return 1
+  elseif !exists("g:pathogen_disabled")
+    return 0
+  endif
+  let sep = pathogen#separator()
+  let blacklist = g:pathogen_disabled
+  return index(blacklist, strpart(a:path, strridx(a:path, sep)+1)) != -1 && index(blacklist, a:path) != 1
+endfunction "}}}1
+
+" Prepend the given directory to the runtime path and append its corresponding
+" after directory.  If the directory is already included, move it to the
+" outermost position.  Wildcards are added as is.  Ending a path in /{} causes
+" all subdirectories to be added (except those in g:pathogen_disabled).
+function! pathogen#surround(path) abort " {{{1
+  let sep = pathogen#separator()
+  let rtp = pathogen#split(&rtp)
+  if a:path =~# '[\\/]{}$'
+    let path = fnamemodify(a:path[0:-4], ':p:s?[\\/]\=$??')
+    let before = filter(pathogen#glob_directories(path.sep.'*'), '!pathogen#is_disabled(v:val)')
+    let after  = filter(reverse(pathogen#glob_directories(path.sep."*".sep."after")), '!pathogen#is_disabled(v:val[0:-7])')
+    call filter(rtp,'v:val[0:strlen(path)-1] !=# path')
+  else
+    let path = fnamemodify(a:path, ':p:s?[\\/]\=$??')
+    let before = [path]
+    let after = [path . sep . 'after']
+    call filter(rtp, 'index(before + after, v:val) == -1')
+  endif
+  let &rtp = pathogen#join(before, rtp, after)
+  return &rtp
+endfunction " }}}1
+
+" Prepend all subdirectories of path to the rtp, and append all 'after'
+" directories in those subdirectories.  Deprecated.
+function! pathogen#runtime_prepend_subdirectories(path) " {{{1
+  call s:warn('Change pathogen#runtime_prepend_subdirectories('.string(a:path).') to pathogen#surround('.string(a:path.'/{}').')')
+  return pathogen#surround(a:path . pathogen#separator() . '{}')
+endfunction " }}}1
+
+" For each directory in the runtime path, add a second entry with the given
+" argument appended.  If the argument ends in '/{}', add a separate entry for
+" each subdirectory.  The default argument is 'bundle/{}', which means that
+" .vim/bundle/*, $VIM/vimfiles/bundle/*, $VIMRUNTIME/bundle/*,
+" $VIM/vim/files/bundle/*/after, and .vim/bundle/*/after will be added (on
+" UNIX).
+function! pathogen#incubate(...) abort " {{{1
+  let sep = pathogen#separator()
+  let name = a:0 ? a:1 : 'bundle/{}'
+  if "\n".s:done_bundles =~# "\\M\n".name."\n"
+    return ""
+  endif
+  let s:done_bundles .= name . "\n"
+  let list = []
+  for dir in pathogen#split(&rtp)
+    if dir =~# '\<after$'
+      if name =~# '{}$'
+        let list +=  filter(pathogen#glob_directories(substitute(dir,'after$',name[0:-3],'').'*'.sep.'after'), '!pathogen#is_disabled(v:val[0:-7])') + [dir]
+      else
+        let list += [dir, substitute(dir, 'after$', '', '') . name . sep . 'after']
+      endif
+    else
+      if name =~# '{}$'
+        let list +=  [dir] + filter(pathogen#glob_directories(dir.sep.name[0:-3].'*'), '!pathogen#is_disabled(v:val)')
+      else
+        let list += [dir . sep . name, dir]
+      endif
+    endif
+  endfor
+  let &rtp = pathogen#join(pathogen#uniq(list))
+  return 1
+endfunction " }}}1
+
+" Deprecated alias for pathogen#incubate().
+function! pathogen#runtime_append_all_bundles(...) abort " {{{1
+  if a:0
+    call s:warn('Change pathogen#runtime_append_all_bundles('.string(a:1).') to pathogen#incubate('.string(a:1.'/{}').')')
+  else
+    call s:warn('Change pathogen#runtime_append_all_bundles() to pathogen#incubate()')
+  endif
+  return call('pathogen#incubate', map(copy(a:000),'v:val . "/{}"'))
+endfunction
+
+let s:done_bundles = ''
+" }}}1
+
+" Invoke :helptags on all non-$VIM doc directories in runtimepath.
+function! pathogen#helptags() abort " {{{1
+  let sep = pathogen#separator()
+  for glob in pathogen#split(&rtp)
+    for dir in split(glob(glob), "\n")
+      if (dir.sep)[0 : strlen($VIMRUNTIME)] !=# $VIMRUNTIME.sep && filewritable(dir.sep.'doc') == 2 && !empty(filter(split(glob(dir.sep.'doc'.sep.'*'),"\n>"),'!isdirectory(v:val)')) && (!filereadable(dir.sep.'doc'.sep.'tags') || filewritable(dir.sep.'doc'.sep.'tags'))
+        helptags `=dir.'/doc'`
+      endif
+    endfor
+  endfor
+endfunction " }}}1
+
+command! -bar Helptags :call pathogen#helptags()
+
+" Execute the given command.  This is basically a backdoor for --remote-expr.
+function! pathogen#execute(...) abort " {{{1
+  for command in a:000
+    execute command
+  endfor
+  return ''
+endfunction " }}}1
+
+" Like findfile(), but hardcoded to use the runtimepath.
+function! pathogen#runtime_findfile(file,count) abort "{{{1
+  let rtp = pathogen#join(1,pathogen#split(&rtp))
+  let file = findfile(a:file,rtp,a:count)
+  if file ==# ''
+    return ''
+  else
+    return fnamemodify(file,':p')
+  endif
+endfunction " }}}1
+
+" Backport of fnameescape().
+function! pathogen#fnameescape(string) abort " {{{1
+  if exists('*fnameescape')
+    return fnameescape(a:string)
+  elseif a:string ==# '-'
+    return '\-'
+  else
+    return substitute(escape(a:string," \t\n*?[{`$\\%#'\"|!<"),'^[+>]','\\&','')
+  endif
+endfunction " }}}1
+
+if exists(':Vedit')
+  finish
+endif
+
+let s:vopen_warning = 0
+
+function! s:find(count,cmd,file,lcd) " {{{1
+  let rtp = pathogen#join(1,pathogen#split(&runtimepath))
+  let file = pathogen#runtime_findfile(a:file,a:count)
+  if file ==# ''
+    return "echoerr 'E345: Can''t find file \"".a:file."\" in runtimepath'"
+  endif
+  if !s:vopen_warning
+    let s:vopen_warning = 1
+    let warning = '|echohl WarningMsg|echo "Install scriptease.vim to continue using :V'.a:cmd.'"|echohl NONE'
+  else
+    let warning = ''
+  endif
+  if a:lcd
+    let path = file[0:-strlen(a:file)-2]
+    execute 'lcd `=path`'
+    return a:cmd.' '.pathogen#fnameescape(a:file) . warning
+  else
+    return a:cmd.' '.pathogen#fnameescape(file) . warning
+  endif
+endfunction " }}}1
+
+function! s:Findcomplete(A,L,P) " {{{1
+  let sep = pathogen#separator()
+  let cheats = {
+        \'a': 'autoload',
+        \'d': 'doc',
+        \'f': 'ftplugin',
+        \'i': 'indent',
+        \'p': 'plugin',
+        \'s': 'syntax'}
+  if a:A =~# '^\w[\\/]' && has_key(cheats,a:A[0])
+    let request = cheats[a:A[0]].a:A[1:-1]
+  else
+    let request = a:A
+  endif
+  let pattern = substitute(request,'/\|\'.sep,'*'.sep,'g').'*'
+  let found = {}
+  for path in pathogen#split(&runtimepath)
+    let path = expand(path, ':p')
+    let matches = split(glob(path.sep.pattern),"\n")
+    call map(matches,'isdirectory(v:val) ? v:val.sep : v:val')
+    call map(matches,'expand(v:val, ":p")[strlen(path)+1:-1]')
+    for match in matches
+      let found[match] = 1
+    endfor
+  endfor
+  return sort(keys(found))
+endfunction " }}}1
+
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Ve       :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vedit    :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vopen    :execute s:find(<count>,'edit<bang>',<q-args>,1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vsplit   :execute s:find(<count>,'split',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vvsplit  :execute s:find(<count>,'vsplit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vtabedit :execute s:find(<count>,'tabedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vpedit   :execute s:find(<count>,'pedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vread    :execute s:find(<count>,'read',<q-args>,<bang>1)
+
+" vim:set et sw=2:
diff --git a/bundle/jedi-vim b/bundle/jedi-vim
new file mode 160000
+Subproject c1026023f273992b14235ae5484fd6b9685de28
diff --git a/bundle/nerdtree b/bundle/nerdtree
new file mode 160000
+Subproject 40d05ace57fb51cc2c2b2e9eb81c4832ed29163
diff --git a/bundle/supertab b/bundle/supertab
new file mode 160000
+Subproject a2268b61edc4ba38d152ecfa7c853a7f1bc7137
diff --git a/bundle/syntastic b/bundle/syntastic
new file mode 160000
+Subproject 60578c35d2a4babd0eab9bb2afafc6cece449e9
diff --git a/bundle/vim-fugitive b/bundle/vim-fugitive
new file mode 160000
+Subproject 00b0916ae2fc4e329f519686348de13d7477d77
diff --git a/bundle/vim-gitgutter b/bundle/vim-gitgutter
new file mode 160000
+Subproject ff031d022f2123353bc93a3aa97290287c10a28
diff --git a/doc/ShowTrailingWhitespace.txt b/doc/ShowTrailingWhitespace.txt
new file mode 100644
index 0000000..9d3f861
--- /dev/null
+++ b/doc/ShowTrailingWhitespace.txt
@@ -0,0 +1,162 @@
+*ShowTrailingWhitespace.txt*	Detect unwanted whitespace at the end of lines.
+
+		  SHOW TRAILING WHITESPACE    by Ingo Karkat
+						  *ShowTrailingWhitespace.vim*
+description			|ShowTrailingWhitespace-description|
+usage				|ShowTrailingWhitespace-usage|
+installation			|ShowTrailingWhitespace-installation|
+configuration			|ShowTrailingWhitespace-configuration|
+integration			|ShowTrailingWhitespace-integration|
+limitations			|ShowTrailingWhitespace-limitations|
+known problems			|ShowTrailingWhitespace-known-problems|
+todo				|ShowTrailingWhitespace-todo|
+history				|ShowTrailingWhitespace-history|
+
+==============================================================================
+DESCRIPTION				  *ShowTrailingWhitespace-description*
+
+This plugin highlights whitespace at the end of each line (except when typing
+at the end of a line). It uses the matchadd()-function, therefore doesn't
+interfere with syntax highlighting and leaves the |:match| command for other
+uses.
+Highlighting can be switched on/off globally and for individual buffers. The
+plugin comes with exceptions for certain filetypes, where certain lines can /
+must include trailing whitespace; additional patterns can be configured.
+
+RELATED WORKS								     *
+
+There are already a number of plugins for this purpose, most based on this
+VimTip:
+    http://vim.wikia.com/wiki/Highlight_unwanted_spaces
+However, most of them use the older :match command and are not as flexible.
+- smartmatcheol.vim (vimscript #2635) highlights based on file extension or
+  name.
+- trailing-whitespace (vimscript #3201) uses :match.
+- bad-whitespace (vimscript #3735) uses :match, allows on/off/toggling via
+  commands.
+- Trailer Trash (vimscript #3938) uses :match.
+- DynamicSigns (vimscript #3965) can show whitespace errors (also mixed
+  indent) in the sign column.
+
+Many plugins also come with a command to strip off the trailing whitespace;
+this plugin separates this into the companion |DeleteTrailingWhitespace.vim|
+plugin (vimscript #0000), which can even remove the trailing whitespace
+automatically on each write.
+
+To quickly locate the occurrences of trailing whitespace, you can use the
+companion |JumpToTrailingWhitespace.vim| plugin (vimscript #0000).
+
+==============================================================================
+USAGE						*ShowTrailingWhitespace-usage*
+
+By default, trailing whitespace is highlighted in all Vim buffers. Some users
+may want to selectively enable / disable this for certain filetypes, or files
+in a particular directory hierarchy, or toggle this on demand. Since it's
+difficult to accommodate all these demands with short and easy mappings and
+commands, this plugin does not define any of them, and leaves it to you to
+tailor the plugin to your needs. See |ShowTrailingWhitespace-configuration|
+below.
+
+==============================================================================
+INSTALLATION				 *ShowTrailingWhitespace-installation*
+
+This script is packaged as a |vimball|. If you have the "gunzip" decompressor
+in your PATH, simply edit the *.vba.gz package in Vim; otherwise, decompress
+the archive first, e.g. using WinZip. Inside Vim, install by sourcing the
+vimball or via the |:UseVimball| command. >
+    vim ShowTrailingWhitespace.vba.gz
+    :so %
+To uninstall, use the |:RmVimball| command.
+
+DEPENDENCIES				 *ShowTrailingWhitespace-dependencies*
+
+- Requires Vim 7.1 with "matchadd()", or Vim 7.2 or higher.
+
+==============================================================================
+CONFIGURATION				*ShowTrailingWhitespace-configuration*
+
+For a permanent configuration, put the following commands into your |vimrc|:
+
+					       *ShowTrailingWhitespace-colors*
+To change the highlighting colors: >
+    highlight ShowTrailingWhitespace Error ctermbg=Red guibg=Red
+<
+						    *g:ShowTrailingWhitespace*
+By default, highlighting is enabled for all buffers, and you can (selectively)
+disable it. To work from the opposite premise, launch Vim with highlighting
+disabled: >
+    let g:ShowTrailingWhitespace = 0
+<
+					 *g:ShowTrailingWhitespace_FilterFunc*
+In addition to toggling the highlighting on/off via
+|g:ShowTrailingWhitespace|, the decision can also be influenced by buffer
+settings or the environment. By default, buffers that are not persisted to
+disk (unless they are scratch buffers) or not modifiable (like user interface
+windows from various plugins) are skipped. You can disable this filtering: >
+    let g:ShowTrailingWhitespace_FilterFunc = ''
+or install your own custom filter function instead: >
+    let g:ShowTrailingWhitespace_FilterFunc = function('MyFunc')
+<
+
+					     *ShowTrailingWhitespace-commands*
+Highlighting can be enabled / disabled globally and for individual buffers.
+Analog to the |:set| and |:setlocal| commands, you can define the following
+commands: >
+    command! -bar ShowTrailingWhitespaceOn          call ShowTrailingWhitespace#Set(1,1)
+    command! -bar ShowTrailingWhitespaceOff         call ShowTrailingWhitespace#Set(0,1)
+    command! -bar ShowTrailingWhitespaceBufferOn    call ShowTrailingWhitespace#Set(1,0)
+    command! -bar ShowTrailingWhitespaceBufferOff   call ShowTrailingWhitespace#Set(0,0)
+To set the local highlighting back to its global value (like :set {option}<
+does), the following command can be defined: >
+    command! -bar ShowTrailingWhitespaceBufferClear call ShowTrailingWhitespace#Reset()
+<
+					     *ShowTrailingWhitespace-mappings*
+You can also define a quick mapping to toggle the highlighting (here, locally;
+for global toggling use ShowTrailingWhitespace#Toggle(1): >
+    nnoremap <silent> <Leader>t$ :<C-u>call ShowTrailingWhitespace#Toggle(0)<Bar>echo (ShowTrailingWhitespace#IsSet() ? 'Show trailing whitespace' : 'Not showing trailing whitespace')<CR>
+<
+					   *ShowTrailingWhitespace-exceptions*
+For some filetypes, in certain places, trailing whitespace is part of the
+syntax or even mandatory. If you don't want to be bothered by these showing up
+as false positives, you can augment the regular expression so that these
+places do not match. The ShowTrailingWhitespace#SetLocalExtraPattern()
+function takes a regular expression that is prepended to the pattern for the
+trailing whitespace. For a certain filetype, this is best set in a file
+    ftplugin/{filetype}_ShowTrailingWhitespace.vim
+
+
+==============================================================================
+INTEGRATION				  *ShowTrailingWhitespace-integration*
+					    *ShowTrailingWhitespace-functions*
+The ShowTrailingWhitespace#IsSet() function can be used to query the on/off
+status for the current buffer, e.g. for use in the |statusline|.
+
+To obtain the pattern for matching trailing whitespace, including any
+|ShowTrailingWhitespace-exceptions|, you can use the function
+ShowTrailingWhitespace#Pattern(0).
+
+==============================================================================
+LIMITATIONS				  *ShowTrailingWhitespace-limitations*
+
+KNOWN PROBLEMS			       *ShowTrailingWhitespace-known-problems*
+
+TODO						 *ShowTrailingWhitespace-todo*
+
+IDEAS						*ShowTrailingWhitespace-ideas*
+
+==============================================================================
+HISTORY					      *ShowTrailingWhitespace-history*
+
+1.00	16-Mar-2012
+First published version.
+
+0.01	25-Feb-2012
+Started development.
+
+==============================================================================
+Copyright: (C) 2012 Ingo Karkat
+The VIM LICENSE applies to this script; see |copyright|.
+
+Maintainer:	Ingo Karkat <ingo@karkat.de>
+==============================================================================
+ vim:tw=78:ts=8:ft=help:norl:
diff --git a/doc/tags b/doc/tags
new file mode 100644
index 0000000..0c8e58f
--- /dev/null
+++ b/doc/tags
@@ -0,0 +1,20 @@
+ShowTrailingWhitespace-colors	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-colors*
+ShowTrailingWhitespace-commands	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-commands*
+ShowTrailingWhitespace-configuration	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-configuration*
+ShowTrailingWhitespace-dependencies	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-dependencies*
+ShowTrailingWhitespace-description	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-description*
+ShowTrailingWhitespace-exceptions	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-exceptions*
+ShowTrailingWhitespace-functions	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-functions*
+ShowTrailingWhitespace-history	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-history*
+ShowTrailingWhitespace-ideas	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-ideas*
+ShowTrailingWhitespace-installation	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-installation*
+ShowTrailingWhitespace-integration	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-integration*
+ShowTrailingWhitespace-known-problems	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-known-problems*
+ShowTrailingWhitespace-limitations	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-limitations*
+ShowTrailingWhitespace-mappings	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-mappings*
+ShowTrailingWhitespace-todo	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-todo*
+ShowTrailingWhitespace-usage	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace-usage*
+ShowTrailingWhitespace.txt	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace.txt*
+ShowTrailingWhitespace.vim	ShowTrailingWhitespace.txt	/*ShowTrailingWhitespace.vim*
+g:ShowTrailingWhitespace	ShowTrailingWhitespace.txt	/*g:ShowTrailingWhitespace*
+g:ShowTrailingWhitespace_FilterFunc	ShowTrailingWhitespace.txt	/*g:ShowTrailingWhitespace_FilterFunc*
diff --git a/ftplugin/diff_ShowTrailingWhitespace.vim b/ftplugin/diff_ShowTrailingWhitespace.vim
new file mode 100644
index 0000000..1d5ea79
--- /dev/null
+++ b/ftplugin/diff_ShowTrailingWhitespace.vim
@@ -0,0 +1,17 @@
+" diff_ShowTrailingWhitespace.vim: Whitespace exceptions for the "diff" filetype.
+"
+" DEPENDENCIES:
+"   - ShowTrailingWhitespace.vim autoload script.
+"
+" Copyright: (C) 2012 Ingo Karkat
+"   The VIM LICENSE applies to this script; see ':help copyright'.
+"
+" Maintainer:	Ingo Karkat <ingo@karkat.de>
+"
+" REVISION	DATE		REMARKS
+"   1.00.001	02-Mar-2012	file creation
+
+" A single space at the beginning of a line can represent an empty context line.
+call ShowTrailingWhitespace#SetLocalExtraPattern( '^\%( \@!\s\)$\|\%>1v')
+
+" vim: set ts=8 sts=4 sw=4 noexpandtab ff=unix fdm=syntax :
diff --git a/ftplugin/mail_ShowTrailingWhitespace.vim b/ftplugin/mail_ShowTrailingWhitespace.vim
new file mode 100644
index 0000000..57afec3
--- /dev/null
+++ b/ftplugin/mail_ShowTrailingWhitespace.vim
@@ -0,0 +1,22 @@
+" mail_ShowTrailingWhitespace.vim: Whitespace exceptions for the "mail" filetype.
+"
+" DEPENDENCIES:
+"   - ShowTrailingWhitespace.vim autoload script.
+"
+" Copyright: (C) 2012 Ingo Karkat
+"   The VIM LICENSE applies to this script; see ':help copyright'.
+"
+" Maintainer:	Ingo Karkat <ingo@karkat.de>
+"
+" REVISION	DATE		REMARKS
+"   1.00.002	16-Mar-2012	Refined pattern.
+"	001	03-Mar-2012	file creation
+
+" - The email signature separator consists of dash-dash-space.
+" - Email headers from Outlook or the Thunderbird "External Editor" add-on
+"   may leave whitespace after mail headers. Ignore them unless it's the
+"   Subject: header.
+" - Quoted empty lines may contain trailing whitespace.
+call ShowTrailingWhitespace#SetLocalExtraPattern( '\%(^\%(--\|\%( \?>\)\+\|\%(From\|Sent\|To\|Cc\|Bcc\):.*\)\)\@<!')
+
+" vim: set ts=8 sts=4 sw=4 noexpandtab ff=unix fdm=syntax :
diff --git a/plugin/ShowTrailingWhitespace.vim b/plugin/ShowTrailingWhitespace.vim
new file mode 100644
index 0000000..da31a5c
--- /dev/null
+++ b/plugin/ShowTrailingWhitespace.vim
@@ -0,0 +1,51 @@
+" ShowTrailingWhitespace.vim: Detect unwanted whitespace at the end of lines.
+"
+" DEPENDENCIES:
+"   - ShowTrailingWhitespace.vim autoload script.
+"   - ShowTrailingWhitespace/Filter.vim autoload script.
+"
+" Copyright: (C) 2012 Ingo Karkat
+"   The VIM LICENSE applies to this script; see ':help copyright'.
+"
+" Maintainer:	Ingo Karkat <ingo@karkat.de>
+"
+" REVISION	DATE		REMARKS
+"   1.00.002	26-Feb-2012	Move functions to autoload script.
+"				Rewrite example commands with new autoload
+"				functions.
+"	001	25-Feb-2012	file creation
+
+" Avoid installing twice or when in unsupported Vim version.
+if exists('g:loaded_ShowTrailingWhitespace') || (v:version == 701 && ! exists('*matchadd')) || (v:version < 701)
+    finish
+endif
+let g:loaded_ShowTrailingWhitespace = 1
+
+"- configuration ---------------------------------------------------------------
+
+if ! exists('g:ShowTrailingWhitespace')
+    let g:ShowTrailingWhitespace = 1
+endif
+if ! exists('g:ShowTrailingWhitespace_FilterFunc')
+    if v:version < 702
+	" Vim 7.0/1 need preloading of functions referenced in Funcrefs.
+	runtime autoload/ShowTrailingWhitespace/Filter.vim
+    endif
+    let g:ShowTrailingWhitespace_FilterFunc = function('ShowTrailingWhitespace#Filter#Default')
+endif
+
+
+"- autocmds --------------------------------------------------------------------
+
+augroup ShowTrailingWhitespace
+    autocmd!
+    autocmd BufWinEnter,InsertLeave * call ShowTrailingWhitespace#Detect(0)
+    autocmd InsertEnter             * call ShowTrailingWhitespace#Detect(1)
+augroup END
+
+
+"- highlight groups ------------------------------------------------------------
+
+highlight def link ShowTrailingWhitespace Error
+
+" vim: set ts=8 sts=4 sw=4 noexpandtab ff=unix fdm=syntax :
diff --git a/pmrc b/pmrc
new file mode 100644
index 0000000..57ffe6b
--- /dev/null
+++ b/pmrc
@@ -0,0 +1,158 @@
+" MISC
+
+" Enable python folding
+let g:pymode_folding = 0
+
+" Documentation
+let g:pymode_doc = 1
+let g:pymode_doc_key = 'K'
+
+" Autoremove unused whitespaces
+let g:pymode_utils_whitespaces = 0
+
+" Enable pymode indentation
+let g:pymode_indent = 0
+
+
+" Load pylint code plugin
+let g:pymode_lint = 1
+
+" Switch pylint, pyflakes, pep8, mccabe code-checkers
+" Can have multiply values "pep8,pyflakes,mcccabe"
+" Choices are pyflakes, pep8, mccabe, pylint, pep257
+let g:pymode_lint_checker = "pyflakes,pep8,pylint"
+
+" Skip errors and warnings
+" E.g. "E501,W002", "E2,W" (Skip all Warnings and Errors startswith E2) and etc
+let g:pymode_lint_ignore = "E501"
+
+" Select errors and warnings
+" E.g. "E4,W"
+let g:pymode_lint_select = ""
+
+" Run linter on the fly
+let g:pymode_lint_onfly = 1
+
+" Pylint configuration file
+" If file not found use 'pylintrc' from python-mode plugin directory
+let g:pymode_lint_config = "$HOME/.pylintrc"
+
+" Check code every save
+let g:pymode_lint_write = 1
+
+" Auto open cwindow if errors be finded
+let g:pymode_lint_cwindow = 0
+
+" Show error message if cursor placed at the error line
+let g:pymode_lint_message = 1
+
+" Auto jump on first error
+let g:pymode_lint_jump = 0
+
+" Hold cursor in current window
+" when quickfix is open
+let g:pymode_lint_hold = 0
+
+" Place error signs
+let g:pymode_lint_signs = 1
+
+" Maximum allowed mccabe complexity
+let g:pymode_lint_mccabe_complexity = 8
+
+" Minimal height of pylint error window
+let g:pymode_lint_minheight = 3
+
+" Maximal height of pylint error window
+let g:pymode_lint_maxheight = 6
+
+" ROPE
+
+" Load rope plugin
+let g:pymode_rope = 1
+
+" Map keys for autocompletion
+let g:pymode_rope_autocomplete_map = '<C-Space>'
+
+" Auto create and open ropeproject
+let g:pymode_rope_auto_project = 1
+
+" Enable autoimport
+let g:pymode_rope_enable_autoimport = 1
+
+" Auto generate global cache
+let g:pymode_rope_autoimport_generate = 1
+
+let g:pymode_rope_autoimport_underlineds = 0
+
+let g:pymode_rope_codeassist_maxfixes = 10
+
+let g:pymode_rope_sorted_completions = 1
+
+let g:pymode_rope_extended_complete = 1
+
+let g:pymode_rope_autoimport_modules = ["os","shutil","datetime"]
+
+let g:pymode_rope_confirm_saving = 1
+
+let g:pymode_rope_global_prefix = "<C-x>p"
+
+let g:pymode_rope_local_prefix = "<C-c>r"
+
+let g:pymode_rope_vim_completion = 1
+
+let g:pymode_rope_guess_project = 1
+
+let g:pymode_rope_goto_def_newwin = ""
+
+let g:pymode_rope_always_show_complete_menu = 0
+
+
+" special highlight
+" Enable pymode's custom syntax highlighting
+let g:pymode_syntax = 1
+
+" Enable all python highlightings
+let g:pymode_syntax_all = 1
+
+" Highlight "print" as function
+let g:pymode_syntax_print_as_function = 0
+
+" Highlight indentation errors
+"let g:pymode_syntax_indent_errors = g:pymode_syntax_all
+
+" Highlight trailing spaces
+let g:pymode_syntax_space_errors = g:pymode_syntax_all
+
+" Highlight string formatting
+let g:pymode_syntax_string_formatting = g:pymode_syntax_all
+
+" Highlight str.format syntax
+let g:pymode_syntax_string_format = g:pymode_syntax_all
+
+" Highlight string.Template syntax
+let g:pymode_syntax_string_templates = g:pymode_syntax_all
+
+" Highlight doc-tests
+let g:pymode_syntax_doctests = g:pymode_syntax_all
+
+" Highlight builtin objects (__doc__, self, etc)
+let g:pymode_syntax_builtin_objs = g:pymode_syntax_all
+
+" Highlight builtin functions
+let g:pymode_syntax_builtin_funcs = g:pymode_syntax_all
+
+" Highlight exceptions
+let g:pymode_syntax_highlight_exceptions = g:pymode_syntax_all
+
+" Highlight equal operator
+let g:pymode_syntax_highlight_equal_operator = g:pymode_syntax_all
+
+" Highlight stars operator
+let g:pymode_syntax_highlight_stars_operator = g:pymode_syntax_all
+
+" Highlight `self`
+let g:pymode_syntax_highlight_self = g:pymode_syntax_all
+
+" For fast machines
+let g:pymode_syntax_slow_sync = 1
+
diff --git a/spell/en.utf-8.add b/spell/en.utf-8.add
new file mode 100644
index 0000000..a1eee2e
--- /dev/null
+++ b/spell/en.utf-8.add
@@ -0,0 +1,66 @@
+Backends
+VPNs
+GPS
+geolocation
+WiFi
+GeoIP
+geocoding
+Nominatim
+backend
+APs
+ssid
+API
+smartphones
+usecase
+backends
+nominatim
+MapQuest
+Geocoder
+init
+geocoder
+Hostip
+MirrorManager
+GeoLocation
+URLs
+LocationResult
+Geoloc
+param
+lang
+ksdata
+XklWrapper
+kickstart
+str
+rtype
+bool
+s
+public_ip_address
+GeolocationBackend
+GeocodingResult
+DBUS
+WGS84
+lon
+bssid
+rssi
+org
+freedesktop
+NetworkManager
+DBus
+AccessPoint
+DeviceType
+HwAddress
+POSIX
+docstrings
+realmd
+addon
+Stef
+pykickstart
+Kolman
+viewport
+GTK
+hostnames
+NTP
+DHCP
+hostname
+DHCPv6
+DHCPv4
+fallback
diff --git a/spell/en.utf-8.add.spl b/spell/en.utf-8.add.spl
new file mode 100644
index 0000000..effbc0b
--- /dev/null
+++ b/spell/en.utf-8.add.spl
diff --git a/unbundle/pyflakes-pathogen b/unbundle/pyflakes-pathogen
new file mode 160000
+Subproject 365e88237c4f5b03d2032e3be84acd8e05698e9
diff --git a/unbundle/python-mode b/unbundle/python-mode
new file mode 160000
+Subproject 6ce0fe1d7b128f832a69240fbcda9ed150ecca1
diff --git a/unbundle/vim-flake8 b/unbundle/vim-flake8
new file mode 160000
+Subproject d1bb8f1d440a4656342bcc536574e0e1627dedc