From 384c5fe974abe35ab11dce4446dc5eed86585a3b Mon Sep 17 00:00:00 2001
From: "Frank Ch. Eigler" <fche@elastic.org>
Date: Thu, 7 Aug 2008 16:47:18 -0400
Subject: samples: separate into subdirectories by subsystem

---
 testsuite/systemtap.examples/network/nettop.stp | 42 +++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100755 testsuite/systemtap.examples/network/nettop.stp

(limited to 'testsuite/systemtap.examples/network/nettop.stp')

diff --git a/testsuite/systemtap.examples/network/nettop.stp b/testsuite/systemtap.examples/network/nettop.stp
new file mode 100755
index 00000000..96db413a
--- /dev/null
+++ b/testsuite/systemtap.examples/network/nettop.stp
@@ -0,0 +1,42 @@
+#! /usr/bin/env stap
+
+global ifxmit, ifrecv
+
+probe netdev.transmit
+{
+        ifxmit[pid(), dev_name, execname(), uid()] <<< length
+}
+
+probe netdev.receive
+{
+        ifrecv[pid(), dev_name, execname(), uid()] <<< length
+}
+
+
+function print_activity()
+{
+        printf("%5s %5s %-7s %7s %7s %7s %7s %-15s\n",
+                "PID", "UID", "DEV", "XMIT_PK", "RECV_PK",
+                "XMIT_KB", "RECV_KB", "COMMAND")
+
+        foreach ([pid, dev, exec, uid] in ifrecv-) {
+                n_xmit = @count(ifxmit[pid, dev, exec, uid])
+                n_recv = @count(ifrecv[pid, dev, exec, uid])
+                printf("%5d %5d %-7s %7d %7d %7d %7d %-15s\n",
+                        pid, uid, dev, n_xmit, n_recv,
+                        n_xmit ? @sum(ifxmit[pid, dev, exec, uid])/1024 : 0,
+                        n_recv ? @sum(ifrecv[pid, dev, exec, uid])/1024 : 0,
+                        exec)
+        }
+
+        print("\n")
+
+        delete ifxmit
+        delete ifrecv
+}
+
+probe timer.ms(5000), end, error
+{
+        print_activity()
+}
+
-- 
cgit