Merge branch 'master' of ssh://sources.redhat.com/git/systemtap into pr6429-comp-unwindsyms

* 'master' of ssh://sources.redhat.com/git/systemtap:
  simplify systemtap.spec configuration vars
  Handles markers with no format string.
  Fixed task_finder.c kernel 2.6.25 change.
  PR6454: fix "stap -l" listing of space-laden probe point names
  Move examples to testsuite/systemtap.examples.
  PR6451: avoid one class of staprun shutdown deadlock (module/.ctl filehandle = 0)
  Made kernel 2.6.25 changes in task_finder.c.
  Move examples to testsuite/systemtap.examples
  PR6416: extend probing blacklist with more init/exit sections

1 files changed, 42 insertions, 0 deletions

diff --git a/testsuite/systemtap.examples/nettop.stp b/testsuite/systemtap.examples/nettop.stp
new file mode 100755
index 00000000..96db413a
--- /dev/null
+++ b/testsuite/systemtap.examples/nettop.stp
@@ -0,0 +1,42 @@
+#! /usr/bin/env stap
+
+global ifxmit, ifrecv
+
+probe netdev.transmit
+{
+        ifxmit[pid(), dev_name, execname(), uid()] <<< length
+}
+
+probe netdev.receive
+{
+        ifrecv[pid(), dev_name, execname(), uid()] <<< length
+}
+
+
+function print_activity()
+{
+        printf("%5s %5s %-7s %7s %7s %7s %7s %-15s\n",
+                "PID", "UID", "DEV", "XMIT_PK", "RECV_PK",
+                "XMIT_KB", "RECV_KB", "COMMAND")
+
+        foreach ([pid, dev, exec, uid] in ifrecv-) {
+                n_xmit = @count(ifxmit[pid, dev, exec, uid])
+                n_recv = @count(ifrecv[pid, dev, exec, uid])
+                printf("%5d %5d %-7s %7d %7d %7d %7d %-15s\n",
+                        pid, uid, dev, n_xmit, n_recv,
+                        n_xmit ? @sum(ifxmit[pid, dev, exec, uid])/1024 : 0,
+                        n_recv ? @sum(ifrecv[pid, dev, exec, uid])/1024 : 0,
+                        exec)
+        }
+
+        print("\n")
+
+        delete ifxmit
+        delete ifrecv
+}
+
+probe timer.ms(5000), end, error
+{
+        print_activity()
+}
+