AC_INIT([dtf-controller], [0.9], [pavel@raiskup.cz])
AC_CONFIG_AUX_DIR([build-aux])
AM_INIT_AUTOMAKE([foreign -Wall -Werror])
AM_SILENT_RULES([yes])
AC_PROG_CC
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_FILES([Makefile])

# Initialize the test suite.
AC_CONFIG_TESTDIR(tests)
AC_CONFIG_FILES([tests/Makefile])
AM_MISSING_PROG([AUTOM4TE], [autom4te])
AC_SUBST([TEST_GEN_FILES_LIST], [.generated_files])

AC_PATH_PROG([SED], [sed])
m4_define([sed_subst_var_pattern], [	-e 's|@$1[[@]]|\$($1)|g' \\])
SED_RULES="\\
sed_subst_var_pattern(ansibleplaybooksdir)
sed_subst_var_pattern(ansiblevarsdir)
sed_subst_var_pattern(bindir)
sed_subst_var_pattern(docdir)
sed_subst_var_pattern(libdir)
sed_subst_var_pattern(libexecdir)
sed_subst_var_pattern(pkgdatadir)
sed_subst_var_pattern(pkgname)
sed_subst_var_pattern(prefix)
sed_subst_var_pattern(resulttemplatedir)
sed_subst_var_pattern(sysconfdir)
sed_subst_var_pattern(TEST_GEN_FILES_LIST)
sed_subst_var_pattern(top_srcdir)
	-e 's|@__FILE__[[@]]|\$@|g'"
SED_CALL="\$(SED) \$(SED_RULES)"
m4_pattern_allow(AM_V_GEN)
INSTANTIATE="\$(AM_V_GEN){ test ! -f \$@ || rm -f \$@ ; } && \$(SED_CALL) \$< > \$@ && chmod -w \$@"
INSTANTIATE_SCRIPT="\$(INSTANTIATE) && chmod +x \$@"
c_s='$(top_srcdir)/config.status'
AC_SUBST([SED_RULES])
AC_SUBST([SED_CALL])
AC_SUBST([INSTANTIATE])
AC_SUBST([INSTANTIATE_SCRIPT])
AC_SUBST([c_s])

AC_OUTPUT