OBJECTS_DIR = .obj
DESTDIR = ../../bin
UI_DIR = .ui
MOC_DIR = .moc
TEMPLATE = app
LIBS += -lkdecore -lkdeui -lkio -L../../lib -lgeneral -lpokemod

# Following is reformatted from the KTIGCC .pro file
win32 {
    CONFIG += exceptions
    KDEPREFIX = $$(KDEPREFIX)
    isEmpty(KDEPREFIX){
        # Try running kde4-config, however chances are it's not in the path or it was compiled with a bad prefix.
        KDEPREFIX = $$system(kde4-config --prefix)
        isEmpty(KDEPREFIX):error("KDE 4 kdelibs not found, set KDEPREFIX.")
        !exists($$KDEPREFIX):error("KDE 4 kdelibs not found, set KDEPREFIX.")
    }
    KDEINCDIR = $$KDEPREFIX/include
    # $$KDEINCDIR/mingw contains the kdewin32 headers, defining stuff like mkdtemp.
    INCLUDEPATH += $$KDEINCDIR/mingw $$KDEINCDIR
    LIBS += -lkdewin32
    QMAKE_LIBDIR = $$KDEPREFIX/lib $$QMAKE_LIBDIR
}else {
    KDEPREFIX = $$system(kde4-config --prefix)
    isEmpty(KDEPREFIX) : error("KDE 4 kdelibs required.")
    exists($$KDEPREFIX/include/kde4/KDE){
        KDEINCDIR = $$KDEPREFIX/include/kde4
    }    else : exists($$KDEPREFIX/include/kde/KDE){
            KDEINCDIR = $$KDEPREFIX/include/kde
        }    else {
        KDEINCDIR = $$KDEPREFIX/include
    }
    INCLUDEPATH += $$KDEINCDIR
    KDELIBDIR = $$KDEPREFIX/lib$$system(kde4-config --libsuffix)
    KDEDEVELLIBDIR = $$KDELIBDIR
    exists($$KDEDEVELLIBDIR/kde4/devel){
        KDEDEVELLIBDIR = $$KDEDEVELLIBDIR/kde4/devel
    }
    !equals(KDEDEVELLIBDIR,/usr/lib) : !equals(KDEDEVELLIBDIR,/usr/lib64){
        QMAKE_LIBDIR = $$KDEDEVELLIBDIR $$QMAKE_LIBDIR
    }
    !equals(KDELIBDIR,/usr/lib):!equals(KDELIBDIR,/usr/lib64){
        !darwin-* : !macx-* {
                LIBS += -Wl,--rpath,"$$KDELIBDIR"
            }
    }
}

CONFIG += qt gui warn_on exceptions

TARGETDEPS += ../../lib/libpokemod.so ../../lib/libgeneral.so

INCLUDEPATH += ../pokemod ../general

SOURCES += AbilityUI.cpp \
 AuthorUI.cpp \
 BadgeUI.cpp \
 CoinListUI.cpp \
 CoinListObjectUI.cpp \
 EggGroupUI.cpp \
 ImageDialog.cpp \
 ItemUI.cpp \
 ItemTypeUI.cpp \
 MapUI.cpp \
 MoveUI.cpp \
 NatureUI.cpp \
 PokemodUI.cpp \
 PokeModr.cpp \
 PokeModrUI.cpp \
 RulesUI.cpp \
 SpeciesUI.cpp \
 SpeciesAbilityUI.cpp \
 SpeciesEvolutionUI.cpp \
 SpeciesItemUI.cpp \
 SpeciesMoveUI.cpp \
 StoreUI.cpp \
 TileDelegate.cpp \
 TilemapModel.cpp \
 TileUI.cpp \
 TimeUI.cpp \
 TypeUI.cpp \
 MapWarpUI.cpp \
 MapWildListEncounterUI.cpp \
 MapTrainerTeamMemberUI.cpp \
 MapWildListUI.cpp \
 PokeModTreeItem.cpp

HEADERS += AbilityUI.h \
 AuthorUI.h \
 BadgeUI.h \
 CoinListUI.h \
 CoinListObjectUI.h \
 EggGroupUI.h \
 ImageDialog.h \
 ItemUI.h \
 ItemTypeUI.h \
 MapUI.h \
 MoveUI.h \
 NatureUI.h \
 ObjectUI.h \
 PokemodUI.h \
 PokeModr.h \
 PokeModrUI.h \
 PokeModTreeItem.h \
 RulesUI.h \
 SpeciesUI.h \
 SpeciesAbilityUI.h \
 SpeciesEvolutionUI.h \
 SpeciesItemUI.h \
 SpeciesMoveUI.h \
 StoreUI.h \
 TileDelegate.h \
 TilemapModel.h \
 TileUI.h \
 TimeUI.h \
 TypeUI.h \
 MapWarpUI.h \
 MapWildListUI.h \
 MapWildListEncounterUI.h \
 MapTrainerTeamMemberUI.h \
 TypechartWidgetItem.h

FORMS += gui/ability.ui \
 gui/abilityeffect.ui \
 gui/author.ui \
 gui/badge.ui \
 gui/coinlist.ui \
 gui/coinlistobject.ui \
 gui/dialog.ui \
 gui/egggroup.ui \
 gui/item.ui \
 gui/itemeffect.ui \
 gui/itemtype.ui \
 gui/map.ui \
 gui/mapeffect.ui \
 gui/maptrainer.ui \
 gui/maptrainerteammember.ui \
 gui/mapwarp.ui \
 gui/mapwildlist.ui \
 gui/mapwildlistencounter.ui \
 gui/move.ui \
 gui/moveeffect.ui \
 gui/nature.ui \
 gui/pokemod.ui \
 gui/pokemodr.ui \
 gui/rules.ui \
 gui/species.ui \
 gui/speciesability.ui \
 gui/speciesevolution.ui \
 gui/speciesitem.ui \
 gui/speciesmove.ui \
 gui/store.ui \
 gui/tile.ui \
 gui/time.ui \
 gui/type.ui

RESOURCES += images/overlays.qrc