# Following is reformatted from the KTIGCC .pro file
win32 {
    KDEPREFIX = $$(KDEPREFIX)
    isEmpty(KDEPREFIX) {
        # Try running kde4-config, however chances are it's not in the path or it was compiled with a bad prefix.
        KDEPREFIX = $$system(kde4-config --prefix)
        isEmpty(KDEPREFIX):error("KDE 4 kdelibs not found, set KDEPREFIX.")
        !exists($$KDEPREFIX):error("KDE 4 kdelibs not found, set KDEPREFIX.")
    }
    KDEINCDIR = $$KDEPREFIX/include
    # $$KDEINCDIR/mingw contains the kdewin32 headers, defining stuff like mkdtemp.
    INCLUDEPATH += $$KDEINCDIR/mingw $$KDEINCDIR $$KDEINCDIR/KDE
    LIBS += -lkdewin32
    QMAKE_LIBDIR = $$KDEPREFIX/lib $$QMAKE_LIBDIR
} else {
    KDEPREFIX = $$system(kde4-config --prefix)
    isEmpty(KDEPREFIX) : error("KDE 4 kdelibs required.")
    exists($$KDEPREFIX/include/kde4/KDE) {
        KDEINCDIR = $$KDEPREFIX/include/kde4
    } else : exists($$KDEPREFIX/include/kde/KDE) {
        KDEINCDIR = $$KDEPREFIX/include/kde
    } else {
        KDEINCDIR = $$KDEPREFIX/include
    }
    INCLUDEPATH += $$KDEINCDIR $$KDEINCDIR/KDE
    KDELIBDIR = $$KDEPREFIX/lib$$system(kde4-config --libsuffix)
    KDEDEVELLIBDIR = $$KDELIBDIR
    exists($$KDEDEVELLIBDIR/kde4/devel) {
        KDEDEVELLIBDIR = $$KDEDEVELLIBDIR/kde4/devel
    }
    !equals(KDEDEVELLIBDIR,/usr/lib) : !equals(KDEDEVELLIBDIR,/usr/lib64) {
        QMAKE_LIBDIR = $$KDEDEVELLIBDIR $$QMAKE_LIBDIR
    }
    !equals(KDELIBDIR,/usr/lib) : !equals(KDELIBDIR,/usr/lib64) {
        !darwin-* : !macx-* {
            LIBS += -Wl,--rpath,"$$KDELIBDIR"
        }
    }
}