AC_INIT(slapi-nis,0.0)
AM_INIT_AUTOMAKE(foreign)
AC_PROG_LIBTOOL
AM_CONDITIONAL(GCC,[test x$GCC = xyes])
AM_MAINTAINER_MODE

AC_ARG_WITH(domain,
	    AS_HELP_STRING([--with-domain=[[example.com]]],
	    		   [select a default domain name]),
	    mydomain=$withval,
	    mydomain=example.com)
mysuffix=`echo "$mydomain" | sed -e 's:^:dc=:g' -e 's:\.:, dc=:g'`
AC_ARG_WITH(server,
	    AS_HELP_STRING([--with-server=[[dirsrv]]],
	    		   [select a specific server implementation (dirsrv)]),
	    server=$withval,
	    server=dirsrv)

case "$server" in
dirsrv)
	PKG_CHECK_MODULES(RUNTIME,nss nspr)
	saved_CFLAGS="$CFLAGS"
	saved_LIBS="$LIBS"
	CFLAGS="$CFLAGS $RUNTIME_CFLAGS"
	LIBS="$LIBS $RUNTIME_LIBS"
	AC_CHECK_HEADER(dirsrv/slapi-plugin.h,
			AC_DEFINE(HAVE_DIRSRV_SLAPI_PLUGIN_H,1,
				[Define if you have <dirsrv/slapi-plugin.h>]),,[
			#include <nspr.h>
			#include <nss.h>
			])
	if test x$ac_cv_header_dirsrv_slapi_plugin_h = xno ; then
		AC_ERROR([<dirsrv/slapi-plugin.h> not found])
	fi
	CFLAGS="$saved_CFLAGS"
	LIBS="$saved_LIBS"
	AC_DEFINE(USE_NSPR_THREADS,1,[Define to use NSPR's threading functions.])
	;;
*)
	RUNTIME_CFLAGS=
	RUNTIME_LIBS=
	AC_CHECK_HEADERS(slapi-plugin.h)
	if test x$ac_cv_header_slapi_plugin_h = xno ; then
		AC_ERROR([<slapi-plugin.h> not found])
	fi
	AC_DEFINE(USE_PTHREADS,1,[Define to use POSIX threading functions.])
esac

mylibdir=`eval echo "$libdir" | sed "s,NONE,${ac_default_prefix},g"`
mylibdir=`eval echo "$mylibdir" | sed "s,NONE,${ac_prefix},g"`
case "$server" in
dirsrv)
	myplugindir="$mylibdir/dirsrv/plugins"
	;;
openldap)
	myplugindir="$mylibdir/openldap"
	;;
*)
	myplugindir="$mylibdir/$PACKAGE"
	;;
esac

AC_SUBST(myplugindir)
AC_SUBST(mydomain)
AC_SUBST(mysuffix)

AC_DEFINE(DEFAULT_MAX_DGRAM_SIZE,YPMAXRECORD,[Define to the default maximum datagram reply size.])
AC_DEFINE(DEFAULT_MAX_VALUE_SIZE,(256 * 1024),[Define to the default maximum map entry key and value size.])
AC_DEFINE(DEFAULT_TARGET_REPLY_SIZE,(4 * 1024),[Define to the default target size for a connected reply fragment.])

AC_CONFIG_HEADER(config.h)
AC_OUTPUT(Makefile src/Makefile plugin.ldif)